model {
    psi ~ dunif(0,1) 			#prior on data augmentation parameter
    alpha0 ~ dnorm(0,(1/200))		#prior on squared Euclidian distance covariate
    sigma ~dunif(0,200)		#prior on spatial-scale parameter
    alpha1<-  1/(2*sigma*sigma)	#parameter defined for part of the detection function
for(i in 1:M){
    z[i] ~ dbern(psi)			# process to include or not include augmented individuals
    S[i,1] ~ dunif(xlim[1],xlim[2])      # uniform state space
    S[i,2] ~ dunif(ylim[1],ylim[2])	# uniform state space
    for(j in 1:ntraps){
   d[i,j] <- pow(pow(S[i,1]-X[j,1],2) + pow(S[i,2]-X[j,2],2),1)	#Latent distance covariate
 }
  for(k in 1:K){
  for(j in 1:ntraps){
    lp[i,k,j] <- exp(alpha0 - alpha1*d[i,j])*z[i]
    cp[i,k,j] <- lp[i,k,j]/(1+sum(lp[i,k,]))
  }
    cp[i,k,ntraps+1] <- 1-sum(cp[i,k,1:ntraps])  
    Ycat[i,k] ~ dcat(cp[i,k,])
  }}
    N <- sum(z[1:M])			                    #derived population size
    A <- ((xlim[2]-xlim[1])*trap.space)*((ylim[2]-ylim[1])*trap.space)*0.0001   #Area
    D <- N/A			                               #derived density
}